【SAS】基礎06_外部ファイルへの出力（FILE・PUTステートメント、フォーマット出力、リスト出力）

FILENAME 参照名 "外部ファイルを出力するフォルダのフルパス名";

DATA _null_;

	SET 出力データセット名;

	FILE 参照名(外部ファイル名) オプション;

	その他のSASステートメント;
	その他のSASステートメント;
	・・・;

	PUT
		変数の書き込み定義
		変数の書き込み定義
		・・・
	;
RUN;

FILENAME 参照名 CLEAR;

【事前準備】
下図のようなデータセットを用意する。
data list_fixed;
	infile datalines;
	input
		@1  first_name  $10.	/*$w.インフォーマット*/
		@1  first_name2 $char10./*$CHARw.インフォーマット*/
		@11 last_name   $10.	/*$w.インフォーマット*/
		@11 last_name2  $char10./*$CHARw.インフォーマット*/
		@21 sex		1.	/*w.dインフォーマット*/
		@22 age		2.	/*w.dインフォーマット*/
	;
datalines;
     Kaori       Ito222
    Hideki    Tanaka135
      Taro    Yamada130
    Hiroki      Sato125
     Mizue     Ishii254
      Yuko    Koyama230
    Ichiro    Suzuki1
    Shinji      Suda127
     Reiko  Yamauchi242
    Mituru    Adachi345
;
run;

【フォーマット出力の例】
上記の事前準備で作成したSASデータセット「list_fixed」をフォーマット出力する。

filename out "C:\Users";
options missing="";

data _null_;
	set list_fixed;
	file out(list_fixed.txt) lrecl=1000 stopover;
	put
		@1  first_name2  $char10.
		@11 last_name2   $char10.
		@21 sex		 1.
		@22 age		 2.
	;
run;

options missing=".";
filename out clear;

・MISSINGオプション
ここでは、欠損値の出力をピリオド「.」からスペースに変更している。欠損値をピリオド「.」のまま出力する機会はあまりない。

・stopover
PUTの出力定義で指定されたカラムが、論理レコード長（lrecl）を超えたときにエラーが出るようにするオプション。

【実行結果】
フォルダ「"C:\Users"」直下に「list_fixed.txt」が出力されている。

【例】
data _null_;
	set list_fixed;
	file out(list_csv.csv) dlm="," dsd lrecl=1000 stopover;

	/*1行目に変数名を出力する*/
	if _n_ = 1 then do;
		put
			"first_name"	","
			"last_name"	","
			"sex" 		","
			"age"
		;
	end;

	/*2行目以降にデータ部分を出力する*/
	put
		first_name
		last_name
		sex
		age
	;
run;

filename out clear;

【実行結果】

【事前準備】
まず、以下のように、サンプルSASデータセットlist_labelを用意する。
data list_label;
	infile datalines dlm="," dsd missover;
	attrib
		first_name	length=$20. label="First Name"
		last_name	length=$20. label="Last Name"
		sex		length=8.   label="Sex"
		age		length=8.   label="Age"
	;
	input
		first_name
		last_name
		sex
		age
	;
datalines;
Kaori,Ito,2,22
Hideki,Tanaka,1,35
Taro,Yamada,1,30
Hiroki,Sato,1,25
Mizue,Ishii,2,54
Yuko,Koyama,2,30
Ichiro,Suzuki,1,.
Shinji,Suda,1,27
Reiko,Yamauchi,2,42
Mituru,Adachi,3,45
;
run;

【CSVファイルを出力する例】
proc export
	data=list_label
	outfile="C:\Users\list_export.csv"			
	dbms=csv	
	replace;
run;

【実行結果】

【タブ区切りで、変数名ではなくラベルを出力する例】
proc export
	data=list_label
	outfile="C:\Users\list_export.tsv"			
	dbms=dlm
	label
	replace;
	delimiter="09"x;
run;

【実行結果】