【SAS】基礎03_変数処理（算術演算子、文字連結、データセットオプション、変数リスト）

data sample_wariate;

	length
		shamei
		name
		w
		$200.
	;

	shamei = "39株式会社";	    *文字値の代入(文字値を引用符で囲む);
	name   = "";         	    *文字欠損値の代入(ﾌﾞﾗﾝｸを引用符で囲む);
	w      = "39" || "株式会社";*連結演算子による連結文字列を代入;
	price  = 39;		    *数値の代入;
	total  = .;		    *数値欠損値の代入(半角ﾋﾟﾘｵﾄﾞで表す);
	v      = 3 + 9 ;       	    *数値演算の結果を代入;
	x      = price + v ;	    *右辺にも変数を指定;
	y      = sum(price, v) ;    *sas関数を指定;
	y      = y + 1;		    *右辺に指定した変数の値を変更;


run;

data sample_renketsu;

	length
		sei
		mei
		name1-name3	
		$20.
	;

	sei = "山田";
	mei = "太郎";
	name1 = sei || "　" || mei;
	name2 = trim(sei) || "　"|| trim(mei);
	name3 = catt(sei, "　", mei);

run;

name1：長さ20バイトの「sei="山田                "」と長さ20バイトの「mei="太郎                "」を連結しているので、長さ20バイトのname1にはseiの部分しか格納されていない。

name2：TRIM関数で末尾の空白を削除しているので、「name2="山田　太郎"」、と意図した通りに格納されている。

name3：末尾の空白を削除して文字列を連結するCATT関数を使用しているので、「name3="山田　太郎"」、と意図した通りに格納されている。

関数名(引数1, 引数2, ・・・)

data sample_func;

	a = 1;
	b = 2;
	c = .;

	total1 = sum(a, b, c);
	total2 = sum(of a b c);

run;

total1：引数をカンマ「,」区切りで指定している。

total2：関数によっては引数をリスト形式「of」で指定することもできる。

関数名(引数1, 引数2, ・・・)

data sample_missing;

	a = 1;
	b = 2;
	c = .;

	mean1  = (a + b + c) / 3;
	mean2  = mean(of a b c);

run;

mean1：算術演算子の場合、欠損値を含む演算の結果は欠損値となる。

mean2：SAS関数の場合、引数内の欠損値を除外し、有効値のみを使って算出する。

計算式に欠損値が含まれていると、「NOTE: 欠損値を含んだ計算により、以下の箇所で欠損値が生成されました。」のNOTEがログに出力される。

data SASデータセット名(オプション名＝値)；

	set SASデータセット名(オプション名＝値);

	SASステートメント ;
	SASステートメント ;
	・・・;

run;

【KEEPステートメントの例】
data sample_keep;

	keep
		a
		b
		mean2
	;

	set sample_missing;

run;

keepステートメントは、DATAステップの最終過程（すべてのオブザべーションの処理が終わって、SASデータセットを完成させる直前）の段階で作用する。
したがってDATAステップのステートメントであるが、記述位置は問わず、どの位置に記述しても結果は同じになる。これを非実行ステートメントという。

【KEEPデータセットオプションの例】
data sample_keep;

	set sample_missing(keep=a b mean2);

run;

データセットオプションは、作成済みの完成したデータセットに対して作用する。ゆえに、PROCステップでも使用することができる。

上記の例だと、どちらを実行しても下図のSASデータセットが作成される。

しかし、KEEPデータセットオプションで必要な変数のみ保持した方がメモリ消費を防げるので、ビッグデータを読込む際は、どちらを使用するかしっかりと考える必要がある。

【DROPステートメントの例】
data sample_drop;

	drop
		c
		mean1
	;

	set sample_missing;

run;

【DROPデータセットオプションの例】
data sample_drop;

	set sample_missing(drop=c mean1);

run;

上記の例だと、どちらを実行しても下図のSASデータセットが作成される。

【RENAMEステートメントの例】
data sample_rename;

	rename
		c    = c_miss
		mean1= mean1_miss
	;

	set sample_missing;

run;

【RENAMEデータセットオプションの例】
data sample_rename;

	set sample_missing(rename=(c=c_miss mean1=mean1_miss));

run;

上記の例だと、どちらを実行しても下図のSASデータセットが作成される。

最後の文字が連続した数字で、その数字以外は同じ名前である一連の変数を指定する。

X1, X2, X3,・・・Xn  → X1－Xn
【例】keep X1 - X10;

SASデータセット内の変数の位置をもとに、ある範囲の変数群を指定する。
※SASデータセット内の変数の位置とは、変数が作成された順番と考えておけばよい。

変数Ａから変数Ｘまで  → Ａ--Ｘ
【例】keep a -- x；

指定した文字列で始まるすべての変数を参照する。

【例】keep x: y:;

この例では、xy, xz, yy, yzなど、「x」と「y」で始まる全ての変数をKEEPする。

SAS関数の引数に上記の変数リストを指定する場合は、OFキーワードが必要となる。

【例①】sum(of x1 - x3 y1 - y3)
【例②】sum(of x1 - x3, of y1 - y3)
【例③】sum(of x1 - x3, y1 - y3)

例①と例②は同じ結果を返すが、例③はXとYの間にカンマ「,」が入っているので、Xはリストとして扱われるが、Yは単なる引き算となる。
つまり、リストとして扱われる範囲は、OFキーワードから、カンマ「,」まで、ということになる。