【SAS】SUMMAY・MEANSプロシジャの基本的な構文と使い方（集計、要約統計量）

data sample;
	infile datalines dlm="," dsd missover;
	input
		type		:8.
		type_name	:$200.
		type_label	:$200.
		rank		:8.
		maker		:$200.
		model		:$200.
		uriage1		:8.
		uriage2		:8.
		uriage3		:8.
		weight		:8.
	;
datalines;
2,Light,軽自動車,9,ダイハツ,タフト,32191,18169,17442,2
1,Passenger,乗用車,2,,ルーミー,77492,12671,17258,0.5
1,Passenger,乗用車,4,トヨタ,カローラ,53864,10712,,0.5
2,Light,軽自動車,8,ダイハツ,ミラ,36159,9857,15312,2
1,Passenger,乗用車,7,日産,ノート,46879,8494,12649,0.5
1,Passenger,乗用車,5,トヨタ,ハリアー,,8374,11612,0.5
1,Passenger,乗用車,6,トヨタ,ライズ,47965,4838,9587,0.5
2,Light,軽自動車,7,スズキ,アルト,36359,,8460,2
1,Passenger,乗用車,8,トヨタ,ヴォクシー,41101,4641,8175,0.5
2,Light,軽自動車,10,日産,デイズ,31558,4294,8022,2
1,Passenger,乗用車,9,ホンダ,フリード,35551,12636,191414,0.5
2,Light,軽自動車,6,スズキ,ハスラー,48221,11229,134321,2
2,Light,軽自動車,1,ホンダ,N-BOX,,10417,124224,2
2,Light,軽自動車,2,スズキ,スペーシア,78698,9903,95521,2
1,Passenger,乗用車,1,トヨタ,ヤリス,119112,9788,84734,0.5
2,Light,軽自動車,3,,タント,69262,7289,84731,2
2,Light,軽自動車,4,ダイハツ,ムーヴ,57761,6317,79726,2
2,Light,軽自動車,5,日産,ルークス,50055,5981,,2
1,Passenger,乗用車,3,トヨタ,アルファード,56778,5359,59674,0.5
1,Passenger,乗用車,10,トヨタ,シエンタ,33753,,58989,0.5
;
run;

proc summary data = sample;
	class type maker;
	var uriage1 - uriage3;
	output
		out = sample_summary
		n(uriage1) = uriage1
		sum(uriage2 - uriage3) = uriage2 - uriage3
	;
run;

proc summary data = sample
			 nway;
	class type maker;
	var uriage1 - uriage3;
	output
		out = sample_summary_nway
		n(uriage1) = uriage1
		sum(uriage2 - uriage3) = uriage2 - uriage3
	;
run;

proc summary data = sample
			 nway
			 missing;
	class type maker;
	var uriage1 - uriage3;
	output
		out = sample_summary_missing
		n(uriage1) = uriage1
		sum(uriage2 - uriage3) = uriage2 - uriage3
	;
run;

/*AUTONAMEなし*/
proc summary data = sample
			 nway
			 missing;
	class type maker;
	var uriage1 - uriage3;
	output
		out = sample_summary_not_autoname
		n(uriage1 - uriage3) = uriage1_n uriage2_n uriage3_n
		sum(uriage1 - uriage3) = uriage1_sum uriage2_sum uriage3_sum
	;
run;

/*AUTONAMEあり*/
proc summary data = sample
			 nway
			 missing;
	class type maker;
	var uriage1 - uriage3;
	output
		out = sample_summary_autoname
		n =
		sum =
		/ autoname
	;
run;

proc summary data = sample
			 nway
			 missing;
	class type maker;
	id type_name type_label;
	var uriage1 - uriage3;
	output
		out = sample_summary_id
		n(uriage1) = uriage1
		sum(uriage2 - uriage3) = uriage2 - uriage3
	;
run;

proc summary data = sample
			 missing
			 print;
	class type maker;
	var uriage1 - uriage3;
run;

proc summary data = sample
			 missing
			 print
			 nmiss var uclm lclm;
	class type maker;
	var uriage1 - uriage3;
run;